Снова об IP-адресе клиента

[xenikk]

Всем привет, AX 3.0 & SQL2000.

Нашел тему, где AndyD показывает как определить ИП клиента
Как получить IP адресс клиента?

И тут возник вопрос - если работать через терминальный сервер с помощью Citrix - то соответственно будет показывать ИП терминального.
Можно ли как то исправить?

[KiselevSA]

Исправить что? Сессия пользователя открыта с терминального сервера, поэтому IP адрес сервера является правильным в данном случае. А вот чтобы выяснить IP адрес компьютера, открывшего сессию, можно из консоли управления Citrix. Придется анализировать подключения и найти нужную сессию. По другому никак. Да и реальный IP можно не получить, если соединение идет через VPN или маршрутизаторы

[AndyD]

Не знаю,как в цитриксе, а в WTS можно сделать так

static void WTSClientAddress(Args _args)
{
    dll dll = new Dll("Wtsapi32.dll");
    DLLFunction WTSOpenServer = new DLLFunction(dll, "WTSOpenServerA");
    DLLFunction WTSCloseServer = new DLLFunction(dll, "WTSCloseServer");
    DLLFunction WTSQuerySessionInformation = new DLLFunction(dll, "WTSQuerySessionInformationA");
    DLLFunction WTSFreeMemory = new DLLFunction(dll, "WTSFreeMemory");

    int handle;
    Binary  ptr = new Binary(4);
    Binary  buf;
    Binary  size = new Binary(4);
    int i;
    #define.WTS_CURRENT_SERVER_HANDLE  (0)
    #define.WTS_CURRENT_SESSION (-1)
    #define.WTSClientAddress(14)
    #define.byteOne     (4+2+0)
    #define.byteTwo     (4+2+1)
    #define.byteThree   (4+2+2)
    #define.byteFour    (4+2+3)
    ;
    WTSOpenServer.arg(ExtTypes::DWord);
    WTSOpenServer.returns(ExtTypes::DWord);
    handle = WTSOpenServer.call(#WTS_CURRENT_SERVER_HANDLE);
    if (handle)
    {
        WTSQuerySessionInformation.arg(ExtTypes::DWord, ExtTypes::DWord, ExtTypes::DWord,
            ExtTypes::Pointer, ExtTypes::Pointer);
        WTSQuerySessionInformation.returns(ExtTypes::DWord);
        if (WTSQuerySessionInformation.call(handle, #WTS_CURRENT_SESSION, #WTSClientAddress,
                ptr, size) && size.dWord(0) > 0)
        {
            buf = new Binary(size.dWord(0));
            buf.attach(ptr.dWord(0), size.dWord(0));
            if (buf.dWord(0) == 2)
            {
                info(strfmt("%1.%2.%3.%4", buf.byte(#byteOne), buf.byte(#byteTwo), buf.byte(#byteThree), buf.byte(#byteFour)));
            }
            WTSFreeMemory.arg(ExtTypes::DWord);
            WTSFreeMemory.call(ptr.dWord(0));
        }

        WTSCloseServer.arg(ExtTypes::DWord);
        WTSCloseServer.call(handle);
    }
}

может и под цитриксом будет работать?

[xenikk]

ммм...спасибо - попробую)) потом скажу..

[KiselevSA]

Цитата:

Сообщение от AndyD

Не знаю,как в цитриксе, а в WTS можно сделать так может и под цитриксом будет работать?

Может и будет, но возвратит, насколько я помню, адрес шлюза для внешних коннектов. С внутренними терминальными соединениями проблем вроде не должно быть

[AndyD]

Ну, я пробовал из VPN соединения через и-нет и у меня возвращался адрес клиента (т.е. мой)

[leva]

Citrix, на сколько я знаю, создает переменные окружения с инфой о подключенном клиенте. Давно делал, сейчас не вспомню что именно и как они называются, но что-то я оттуда вытаскивал. Рекомендую посмотеть в эту сторону.

[Logger]

Цитата:

Сообщение от xenikk

ммм...спасибо - попробую)) потом скажу..

Получилось ?

[Logger]

Цитата:

Сообщение от AndyD

может и под цитриксом будет работать?

Ура !
Работает !

Только мне лучше было бы знать имя компа. Вы не подскажете как ?

[AndyD]

А почему не должно получиться?

Я подключился через терминалку к удаленному серверу, на нем поднял еще одну удаленную сессию к терминальному серверу и на нем уже запустил Аксапту в трехзвенке. Все это удавольствие через VPN соединение

Это имя и адрес промежуточного сервера.

Только, что бы имя клиента получить надо переделать вызовы

   ...
   #define.WTSClientName(10)
   ...
        if (WTSQuerySessionInformation.call(handle, #WTS_CURRENT_SESSION, #WTSClientName,
                ptr, size) && size.dWord(0) > 0)
        {
            buf = new Binary(size.dWord(0));
            buf.attach(ptr.dWord(0), size.dWord(0));

            if (buf.string(0))
                info(strfmt("%1", buf.string(0)));

            WTSFreeMemory.call(ptr.dWord(0));
        }

[Logger]

Отлично !

То что надо !

Только на вот эту строку

WTSFreeMemory.call(ptr.dWord(0));

у меня выругалась.

Поставил

            WTSFreeMemory.arg(ExtTypes::DWord);
            WTSFreeMemory.call(ptr.dWord(0));

- все нормально.
опечатка была ?

[AndyD]

А, ну да.
Я ее просто вынес перед вызовом if ()

[Logger]

Еще одно уточнение

        if (WTSQuerySessionInformation.call(handle, #WTS_CURRENT_SESSION, #WTSClientAddress,
                ptr, size) && size.dWord(0) > 0)
        {
            buf = new Binary(size.dWord(0));
            buf.attach(ptr.dWord(0), size.dWord(0));
            if (buf.dWord(0) == 2)
            {
                info(strfmt("%1.%2.%3.%4", buf.byte(#byteOne), buf.byte(#byteTwo), buf.byte(#byteThree), buf.byte(#byteFour)));
            }
            WTSFreeMemory.arg(ExtTypes::DWord);
            WTSFreeMemory.call(ptr.dWord(0));
        }

в таком коде тело

            WTSFreeMemory.arg(ExtTypes::DWord);
            WTSFreeMemory.call(ptr.dWord(0));

исполняется только если мы зашли терминальной сессией.
Иначе оно пропущено. Утечки памяти не будет ?

[AndyD]

Нет.
Если вызов функции не прошел, или размер полученного буфера равен нулю, то, собственно, освобождать нечего. Память и так не была размещена

[Logger]

Цитата:

Сообщение от AndyD

Ну, я пробовал из VPN соединения через и-нет и у меня возвращался адрес клиента (т.е. мой)

Да, все верно.
Вот только если я сижу через роутер, то возвращается локальный адрес подсети.
Например такой
192.168.1.3


А реальный ip адрес, который от провайдера выделен, можно поймать ?

[AndyD]

Т.е. вы сидите за NAT, а терминалка на другом конце торчит наружу портом?

[Logger]

Цитата:

Сообщение от leva

Citrix, на сколько я знаю, создает переменные окружения с инфой о подключенном клиенте. Давно делал, сейчас не вспомню что именно и как они называются, но что-то я оттуда вытаскивал. Рекомендую посмотеть в эту сторону.

Поковырял переменные окружения - ничего нет.

Кто-нибудь может подсказать как из клиента аксапты определить версию клиента цитрикса ?

[AlexeyS]

может быть через PowerShell?
[System.Diagnostics.FileVersionInfo]::GetVersionInfo("c:\\windows\\system32\\mstsc.exe").FileVersion
[System.Diagnostics.FileVersionInfo]::GetVersionInfo("C:\Program Files (x86)\Citrix\ICA Client\SelfServicePlugin\SelfService.exe").FileVersion

[Raven Melancholic]

Цитата:

Сообщение от AlexeyS

может быть через PowerShell?

Ну если нужно "Из клиента Аксапты" и можно получить при помощи NET, то PowerShell тут лишнее.
Другой вопрос, сработают ли эти вызовы из клиента для обычного пользователя с его набором прав?
PS: это не претензия, а вопрос.

[AlexeyS]

Цитата:

Сообщение от Raven Melancholic

Ну если нужно "Из клиента Аксапты" и можно получить при помощи NET, то PowerShell тут лишнее.
Другой вопрос, сработают ли эти вызовы из клиента для обычного пользователя с его набором прав?
PS: это не претензия, а вопрос.

точно, можно и напрямую

PHP код:

    System.Diagnostics.FileVersionInfo ff;
    ;
    
    ff = System.Diagnostics.FileVersionInfo::GetVersionInfo("c:\\windows\\system32\\mstsc.exe");
    info(ff.get_FileVersion());
    info(ff.get_FileDescription());