Find для Common-а

[lev]

может кому пригодиться ради спортивного интереса создал у себя следующее:
1. В классе SysDictTable метод find():

static Common find(TableId  _tableId, RefRecId  _recId, boolean _forUpdate = false)
{
    Common      common;
    DictTable   dictTable;
    ;

    if (_recId != 0)
    {
        dictTable   = new DictTable(_tableId);
        common = dictTable.makeRecord();

        common.selectForUpdate(_forUpdate);

        select firstOnly common
            where common.RecId  == _recId;
    }

    return common;
}

2. Job для теста метода:

static void testFindCommon(Args _args)
{
    InventTable inventTable;
    Common      common;
    ;

    select firstonly inventTable;
    // без forUpdate -->
    common  = SysDictTable::find(inventTable.TableId, inventTable.RecId);

    info(strFmt('До update - %1', common.(fieldNum(InventTable, ItemId))));
    // без forUpdate <--

    // с forUpdate -->
    ttsbegin;

    common  = SysDictTable::find(inventTable.TableId, inventTable.RecId, true);
    common.(fieldNum(InventTable, ItemId)) = common.(fieldNum(InventTable, ItemId)) + 'Тест';
    common.doUpdate();

    ttscommit;

    info(strFmt('После update - %1', common.(fieldNum(InventTable, ItemId))));
    // с forUpdate <--
}